Amiga Plus 2002 #11/Amiga Plus CD - 2002 - No. 11.iso/Tools/AmigaSystem/AmiStart/AmiStart.install

Text File | 2002-10-27 | 7.6 KB | 306 lines

;AmiStart Install Script V0.60

(SET WelcomeToAmiStart "Welcome to the AmiStart installation...you should first start AmiStart without installing it to see if you like it")
(SET EndMessage "please read the documentation especially the History and the Usage/ToolTypes section coz this install script only enables some options of AmiStart")
(SET newPrefs 0)
(SET newIcon 0)
(SET newGraphics 0)

(SET @default-dest "clips:")

(MESSAGE WelcomeToAmiStart)

(SET @default-dest
    (ASKDIR (PROMPT "Select a destination for the executable: \n(no drawer will be created)")
        (HELP "this is the path for the AmiStart executable, nolmaly SYS:WbStartup")
        (DEFAULT @default-dest)))

(SET destIcon (TACKON @default-dest "AmiStart.info"))

(COPYFILES (SOURCE "AmiStart") (DEST @default-dest))

(IF (EXISTS destIcon)
    (
        (IF (ASKBOOL
                (PROMPT "do you want to overwrite old AmiStart icon")
                (HELP "this could overwrite some TOOLTYPES, normaly choose NO but this will leave all ToolTypes as they are and will not create any new.\nI recommend to choose yes")
            )
            (
                (SET newIcon 1)
                (COPYFILES
                    (SOURCE "AmiStart.info")
                    (DEST @DEFAULT-DEST)
                )
            )
        )
    )
    (
        (SET newIcon 1)
        (COPYFILES
            (SOURCE "AmiStart.info")
            (DEST @DEFAULT-DEST)
        )
    )
)

(SET @prefs-dest "")

(IF (> newIcon 0)
    (IF (ASKBOOL
            (PROMPT "do you want to install a default prefs file \n(notice: see HELP)")
            (HELP "you can use your old, but you must use one\nthis must be done by the first installation\nfurther installations have already configured prefs files")
        )
        (
            (SET @prefs-dest
                (ASKDIR
                    (PROMPT "Select a destination for the (default) prefs file:\n(no drawer will be created)")
                    (HELP "this ist the path for the AmiStart default prefs file, nolmaly SYS:WbStartup")
                    (DEFAULT @default-dest)
                )
            )
            (COPYFILES (SOURCE "sm.prefs") (DEST @prefs-dest))
            (SET newPrefs 1)
        )
    )
)

(SET @icon-dest "")

(IF (ASKBOOL
        (PROMPT "do you want to install a default graphics package")
        (HELP "this are item-icons/logos for AmiStart, skip if you have already installed one package")
    )
    (
        (SET @icon-dest
            (ASKDIR
                (PROMPT "Select a destination for the graphical data:\n(two drawers named icons and textures will be created)")
                (HELP "this ist the path for the AmiStart icon files")
                (DEFAULT @default-dest)
            )
        )
        (SET IconDir (TACKON @icon-dest "icons"))
        (SET TextureDir (TACKON @icon-dest "textures"))
        (MAKEDIR IconDir)
        (MAKEDIR TextureDir)
        (COPYFILES (SOURCE "Icons") (DEST IconDir) (ALL))
        (COPYFILES (SOURCE "Textures") (DEST TextureDir) (ALL))
        (SET newGraphics 1)
    )
)

(IF (ASKBOOL
        (PROMPT "do you want to install example modules and tools\n(a directory named modules will be created)")
        (HELP "see the documentation")
    )
    (
        (SET ModulesDir (TACKON @icon-dest "modules"))
        (MAKEDIR ModulesDir)
        (COPYFILES (SOURCE "modules") (DEST ModulesDir) (ALL))
    )
)

(IF (ASKBOOL
        (PROMPT "do you want to install alternative mui buttons for the setup windows\n(a directory named buttons will be created)")
        (HELP "these images are only used by AmiStart")
    )
    (
        (SET ButtonsDir (TACKON @icon-dest "buttons"))
        (MAKEDIR ButtonsDir)
        (COPYFILES (SOURCE "buttons") (DEST ButtonsDir) (ALL))
    )
)

(IF (ASKBOOL
        (PROMPT "do you want use Shapes")
        (HELP "Shapes are freeform Buttons on the Workbench")
    )
    (
        (SET ShapesDir (TACKON @icon-dest "shapes"))
        (MAKEDIR ShapesDir)
        (IF (ASKBOOL
                (PROMPT "do you want install the example Voyager Control Shape")
                (HELP "you can control some functions of the Voyager Browser\nartwork by Martin Mason Merz")
            )
            (
                (COPYFILES (SOURCE "shapes/") (DEST ShapesDir) (ALL))
            )
        )


    )
)


(SET ami_languages
(ASKOPTIONS (PROMPT "select additional catalog files for AmiStart (english is buildin)")
    (HELP "select additional languages for AmiStart...")
    (CHOICES "deutsch")
    (DEFAULT 0)
))

(if (> ami_languages 0) (
   (set Cat_dir "locale:catalogs")
   (if (bitand ami_languages 1)         ((set lang "deutsch") (copyfiles (source (tackon "Catalogs" lang)) (choices "AmiStart.catalog") (dest (tackon Cat_dir lang)))))
))


(SET @doc-dest "")

(IF (ASKBOOL
        (PROMPT "do you want to install the documentation")
        (HELP "")
    )
    (
        (SET @doc-dest
            (ASKDIR
                (PROMPT "Select a destination for the documentation:\n(no drawer will be created)")
                (HELP "")
                (DEFAULT @default-dest)
            )
        )
        (COPYFILES (SOURCE "AmiStart.guide") (INFOS) (DEST @doc-dest))
    )
)

(SET docpath (TACKON @doc-dest "AmiStart.guide"))

(SET AmiIcon (TACKON @default-dest "AmiStart"))

(IF (> newIcon 0)
    (
        (TOOLTYPE
            (DEST AmiIcon)
            (SETTOOLTYPE "HELPFILE" docpath)
        )

        (IF (> newPrefs 0)
            (
                (SET AmiPrefs (TACKON @prefs-dest "sm.prefs"))
                (TOOLTYPE
                    (DEST AmiIcon)
                    (SETTOOLTYPE "PREFS" AmiPrefs)
                )
            )
        )

        (IF (> newGraphics 0)
            (
                (SET AmiStartIcon (TACKON IconDir "start"))
                (TOOLTYPE
                    (DEST AmiIcon)
                    (SETTOOLTYPE "STARTICON" AmiStartIcon)
                    (SETTOOLTYPE "DATAPATH" @icon-dest)
                )
            )
        )

        (IF (ASKBOOL
                (PROMPT "do you want to use the AmiStart TaskBar")
                (HELP "")
            )
            (TOOLTYPE
                (DEST AmiIcon)
                (SETTOOLTYPE "TASKBAR" "")
            )


            (IF (ASKBOOL
                    (PROMPT "do you want to make AmiStart invisible")
                    (HELP "using this flag causes AmiStart to be invisible on the Workbench")
                )
                (
                    (TOOLTYPE
                        (DEST AmiIcon)
                        (SETTOOLTYPE "SILENT" "")
                    )
                    (IF (ASKBOOL
                            (PROMPT "do you want to make AmiStart to AutoPopup when\nmouse reaches leftmost bottom position")
                            (HELP "using this flag causes AmiStart to visible when the mousepointer reaches the leftmost bottem position")
                        )
                        (TOOLTYPE
                            (DEST AmiIcon)
                            (SETTOOLTYPE "AUTOPOPUP" "")
                        )
                    )
                )
                (IF (ASKBOOL
                        (PROMPT "do you want to make AmiStarts starticon transparent (Warning: see HELP)")
                        (HELP "this has some restrictions, see docs")
                    )
                    (TOOLTYPE
                        (DEST AmiIcon)
                        (SETTOOLTYPE "TRANSPARENT" "")
                    )
                )
            )
        )

        (SET @hotkey
            (ASKSTRING
                (PROMPT "change the Hotkey to popup AmiStart")
                (HELP "pressing this hotkey popups/hides AmiStart\nfor example\nctrl p\nlalt ctrl a\nlamiga u")
                (DEFAULT "ctrl p")
            )
        )

        (TOOLTYPE
            (DEST AmiIcon)
            (SETTOOLTYPE "CX_HOTKEY" @hotkey)
        )

        (IF (ASKBOOL
            (PROMPT "do you want to use the old fast scaling algorithm for small items (see HELP)")
            (HELP "fast scaling is a bit faster but the items are looking bad,\nfast scaling should be used on non true/hi color views")
            )

            (TOOLTYPE
                (DEST AmiIcon)
                (SETTOOLTYPE "FASTSCALE" "")
            )
        )

        (IF (ASKBOOL
            (PROMPT "do you want to use iconobject.library for loading icons (see HELP)")
            (HELP "the iconobject.library is a part from the Scalos package\nfor example you can use newicons without the newicon patch")
            )

            (TOOLTYPE
                (DEST AmiIcon)
                (SETTOOLTYPE "USEICONOBJECT" "")
            )
        )

        (IF (ASKBOOL
                (PROMPT "do you want to load icons late (see HELP)")
                (HELP "normaly AmiStart loads icons while bootup, using this flag icons will be loaded if you first open their window this allows AmiStart to boot faster and if not all Icons are used less memory is needed")
            )

            (TOOLTYPE
                (DEST AmiIcon)
                (SETTOOLTYPE "LATELOAD" "")
            )
        )

        (IF (ASKBOOL
                (PROMPT "do you want to use a existing extern info-module (see HELP)")
                (HELP "you can use the standard info-requester or a seperate one\nfor example the information.module from the scalos package")
            )
            (
                (SET @info-module
                    (ASKFILE
                        (PROMPT "Select a info module")
                        (HELP "")
                        (DEFAULT "information.module")
                    )
                )
                (TOOLTYPE
                    (DEST AmiIcon)
                    (SETTOOLTYPE "INFOMODULE" @info-module)
                )

            )
        )
    )
)

(MESSAGE EndMessage)